; SAVE#D3:WMJEND.M65
;   .OPT NO LIST
;
      .OPT NO EJECT
;
;     WMJEND.M65
;    MAH JONG WILLIAMS
STADD =   GOPLAY
CTEND =   $C000
CTADD = $BF00
CTDST = $1100
BUILD = $6000
OFFSET = CTADD-CTDST-BUILD
;
    .SET 6,$4E00
    *=  $1100
;
TIPTAB
    .BYTE $20,$60,$A0,$08
    .BYTE $01,$A0,$10,$00
    .BYTE $1D,$A1,$27,$00
    .BYTE $0A,$A0,$45,$04
    .BYTE $15,$AB,$26,$04
    .BYTE $20,$A0,$3B,$05
    .BYTE $20,$A0,$5B,$06
    .BYTE $01,$A0,$7B,$07
;
DO_OVER
    LDA TIPTAB,X
    STA $E4
    INX 
    LDA TIPTAB,X
    STA $E1
    INX 
    LDA TIPTAB,X
    STA $E3
    INX 
    LDA TIPTAB,X
    TAY 
    STA $D500,Y
    INX 
    LDY #$00
    STY $E0
    STY $E2
?3  LDA ($E0),Y
    STA ($E2),Y
    INY 
    BNE ?3
    INC $E1
    INC $E3
    DEC $E4
    BNE ?3
    RTS 
;
GOPLAY
    JSR $4C74
    INC $42
    STA $D400
    LDA # <MEAN
    STA $02
    STA $0A
    STA $0C
    LDA # >MEAN
    STA $03
    STA $0B
    STA $0D
    INC $09
    LDA #$04
    LDX #$10
    JSR ?2
    JMP $728B
;
START2
    LDX #$00
    LDA #$04
?2  STA $E5
?4  JSR DO_OVER
    DEC $E5
    BNE ?4
    LDA #$C0
    STA $02E4
    STA $6A
    STY $D508
    STY $03FA
    STY $42
    RTS 
;
MEAN
    LDA #$00
    INC $42
    STA $D400
    STA $D500
    JMP $E477
;
    .SET 6,$A000
    *=  $BFFA-$3B
INIT STX $03E9  ;CKEY=0
    STX $03EA   ;CASSBT=0
    DEX 
    STX $D301   ;KILL BASIC HARD
    LDA #$01
    STA $09     ;SAY BOOTED
    STA $42
    STA $03F8   ;KILL BASIC SOFT
    LDA # <STADD ;LOAD
    STA $0A     ;DOSVEC WITH
    STA $0C     ;DOSINI AND
    STA $02     ;CASINI WITH
    LDA # >STADD ;LOAD
    STA $0B     ;DOSVEC+1
    STA $0D     ;DOSINI+1
    STA $03     ;CASINI+1
    LDY #$00
    LDA # >CTADD
    STA $E1
    LDA # >CTDST
    STA $E3
    STY $E0
    STY $E2
?A  LDA ($E0),Y
    STA ($E2),Y
    INY 
    BNE ?A
    JMP START2
;
XTLEN = *-INIT
    *=  $BFFA
    .BYTE "FU"
    .BYTE $00   ;MUST BE 0
    .BYTE $00   ;DOS=5,NODOS=4
    .WORD INIT
;ORIGIN AT 150