; SAVE#D3:LORDORB.M65
;   .OPT NO LIST
;
      .OPT NO EJECT
;
;    LORD O ORB WILLIAMS
STADD =   $1DD7
INADD =   $1D63
CTEND =   $C000
CTADD = $BF00
CTDST = $0400
BUILD = $6000
OFFSET = CTADD-CTDST-BUILD
;
    .SET 6,$5B00
    *=  $0400
;
TIPTAB
    .BYTE $20,$60,$A0,$08
    .BYTE $1F,$A0,$1D,$00
    .BYTE $20,$A0,$3C,$01
    .BYTE $20,$A0,$5C,$02
    .BYTE $20,$A0,$7C,$03
;
DO_OVER
    LDA TIPTAB,X
    STA $E4
    INX 
    LDA TIPTAB,X
    STA $E1
    INX 
    LDA TIPTAB,X
    STA $E3
    INX 
    LDA TIPTAB,X
    TAY 
    STA $D500,Y
    INX 
    LDY #$00
    STY $E0
    STY $E2
?3  LDA ($E0),Y
    STA ($E2),Y
    INY 
    BNE ?3
    INC $E1
    INC $E3
    DEC $E4
    BNE ?3
    RTS 
;
START2
    LDA #$05
    STA $E5
    LDX #$00
?4  JSR DO_OVER
    DEC $E5
    BNE ?4
    STY $D508
    LDA #$FF
    STA $06FE
    STA $9FFC
    LDA #$F1
    STA $0929
    LDA #$F7
    STA $1929
    LDA #$C0
    STA $02E4
    STA $02E6
    STA $6A
    CLC 
    TYA 
    STA $03FA
    STY $42
    RTS 
;
    .SET 6,$A000
    *=  $BFFA-$3B
INIT STX $03E9  ;CKEY=0
    STX $03EA   ;CASSBT=0
    DEX 
    STX $D301   ;KILL BASIC HARD
    LDA #$01
    STA $09     ;SAY BOOTED
    STA $42
    STA $03F8   ;KILL BASIC SOFT
    LDA # <STADD
    STA $0A     ;DOSVEC WITH
    LDA # >STADD
    STA $0B     ;DOSVEC+1
    LDA # <INADD
    STA $0C     ;DOSVEC WITH
    LDA # >INADD
    STA $0D     ;DOSVEC+1
    LDY #$00
    LDA # >CTADD
    STA $E1
    LDA # >CTDST
    STA $E3
    STY $E0
    STY $E2
?A  LDA ($E0),Y
    STA ($E2),Y
    INY 
    BNE ?A
    JMP START2
;
XTLEN = *-INIT
    *=  $BFFA
    .BYTE "FU"
    .BYTE $00   ;MUST BE 0
    .BYTE $00   ;DOS=5,NODOS=4
    .WORD INIT
;ORIGIN AT 150